文档章节

【备用】非常不错的ASP操作数据库类,支持多数据库MSSQL,ACCESS,ORACLE,MYSQL等

深圳大道
 深圳大道
发布于 2016/12/29 15:39
字数 4734
阅读 2
收藏 0
可同时操作多个不同类型的数据库。 
完全不用考虑数据类型的差别,再也不用想字符型字段加不加单引号。 
调用非常简单,对数据库的主要操作一般只需要一行代码。 
支持mssql事务回滚。 
可自动生成和输出sql语句方便调试。 
使用方法: 

1. 修改clsDbctrl.asp文件中的第1行为你自己的数据库位置(修改方法参考下面的CreatConn函数说明)。如需连接多个数据库可自行添加,格式相同。 

2. 在你新建的asp文件中包含此asp文件。如: 
<!--#include file="Inc/clsDbctrl.asp" --> 或者: 
<!--#include virtual="/Inc/clsDbctrl.asp"--> 

3.使用如下代码应用此类: 
一个数据库连接: 

<% 
OpenConn() '打开数据库连接 
Dim db : Set db = New DbCtrl '建立对像 
'Your Code Here...... 
Co(db) : CloseConn() '释放对象,关闭数据库连接 
%> 

或者(一个或者多个数据库连接): 

<% 
Dim db1 : Set db1 = New DbCtrl : db1.dbConn = Oc(a) 
Dim db2 : Set db2 = New DbCtrl : db2.dbConn = Oc(b) 
'Your Code Here...... 
Co(db1) : Co(db2) 
%> 

4.具体操作的例子可以参考各函数说明内的代码示例。 

方法和属性概览(详细用法及例子在下面): 

引用: 
CreatConn 生成数据库连接字符串 
Oc 建立数据库连接 
Co 释放对像 
OpenConn 打开默认数据库连接 
CloseConn 关闭默认数据库连接 
dbCtrl.dbConn 属性,获取要操作的数据库连接,默认值为Conn 
dbCtrl.dbErr 属性,只读,输出捕获的错误信息 
dbCtrl.Version 属性,只读,程序版本信息 
dbCtrl.AutoId 方法,自动获取唯一序列号 
dbCtrl.GetRecord 方法,取得符合条件的纪录集 
dbCtrl.GetRecordBySql 方法,根据sql语句取得纪录集 
dbCtrl.GetRecordDetail 方法,根据某一条指定纪录的详细数据 
dbCtrl.AddRecord 方法,添加一个新的纪录 
dbCtrl.UpdateRecord 方法,根据指定条件更新纪录 
dbCtrl.DeleteRecord 方法,删除符合条件的纪录 
dbCtrl.ReadTable 方法,根据指定条件获取某条纪录中的其他字段的内容 
dbCtrl.C 方法,关闭纪录集对像 
dbCtrl.wGetRecord, 
dbCtrl.wAddRecord, 
dbCtrl.wUpdateRecord, 
dbCtrl.wDeleteRecord 这4个方法是取得相应的操作(前面加w)的sql语句 


参数约定: 

由于ASP没有Arguments对象,不能使用动态参数,所以,在本类的代码中,使用了Array(数组)来达到这一效果。本类中的部分参数可以使用数组(参数说明中有注明),但使用数组时应参照以下格式: 

Array("Field1:Value1", "Field2:True", "Field3:100") 

对,有点像json的格式,如果涉及到变量,那就这样: 

Array("Field1:" & Value1, "Field2:" & Value2, "Field3:" & Value3) 

可以这样说,本类中的几乎所有与数据库字段相关的内容都可以用以上的数组格式来设置条件或者是获取内容。而这裡最大的特点就是在使用时不用去考虑字段的类型,在字段后跟一个冒号,接着跟上相应的值就行了。如果你经常手写ASP程序的话,你很快就会感受到运用这种方式的魅力,除了数据类型不用考虑之外,它也很方便随时添加和删除条件。如果你还不明白怎麽用的话没关係,下面有很多例子可以说明这个问题。 

要把ASP的数据库操作封装起来其实并不难,相信大家以前自己也做过类似的代码或是借用过其他人的封装好的代码。但是就如各位知道的一样,使用封装后的代码一旦出错,排错是一个比较麻烦的事情,一般说来,封装后操作越简单的排错也越複杂。俺在写这些代码的时候已经尽我所能考虑到如果出错的话如何去排查错误,在尽可能简化用户操作数据库的代码的同时可以随时输出sql语句排查错误。 

最后需要说明一点,本文所涉及的ASP数据库操作并不适合大型数据,如你所知,操作大型数据最好还是使用存储过程之类的东东比较好,以后俺会考虑把对存储过程的操作也封装进去。还有一个效率问题,要追求高效率的话,用ASP还是应该考虑COM+等,所以再次声明,本类适用的对象是中小型ASP项目。 

好了,下面奉上详细使用说明: 

一.数据库连接 

考虑到大多数人的使用习惯,在数据库连接上使用了公共过程,所以需要大家在代码裡自行修改,如果你已经建立了数据库连接,把这几行注释掉就行了。代码中内置了MSSql,Access,MySQL,Oracle4种数据库的连接方式,当然你也可以自行在源代码中增加或删除。修改例如: 

Dim a : a = CreatConn(0, "TestData", "localhost", "username", "userpassword") 
Dim b : b = CreatConn(1, "Data/%TestDb%.mdb", "", "", "") 

说明一下,第1个参数可以是字符串。如果是使用Access,则第2个参数输入相对路径和绝对路径都是可以的,如有密码也可以在第5个参数中输入,如: 

Dim c : c = CreatConn("ACCESS", "E:\MyWeb\Data\%TestDB%.mdb", "", "", "mdbpassword") 

相关函数: 

原 型:CreatConn(dbType, strDB, strServer, strUid, strPwd) 
功 能:建立数据库连接字符串 
返回值:String 
参 数: 
dbType : Integer or String 连接数据库类型 
(0 or "MSSQL") - Microsoft SQL Server 
(1 or "ACCESS") - Microsoft Office Access 
(2 or "MYSQL") - MySQL Server 
(3 or "ORACLE") - oracle Server 
strDB : String 数据库名或数据库地址(Access使用绝对或者相对路径均可) 
strServer : String 数据库服务器地址,Access请留空 
strUid : String 数据库用户名,Access请留空 
strPwd : String 数据库密码 

原 型:Oc(connStr) 
功 能:打开数据库连接 
返回值:Object 数据库连接对像 
参 数: 
connStr : String 数据库连接字符串,由CreatConn函数生成 

原 型:Co(obj) 
功 能:关闭对像 
参 数: 
obj : Object 要关闭的对象名称 

原 型:OpenConn 
功 能:打开默认数据库连接,会自动建立一个名称为Conn的连接对像 
参 数:无 

原 型:CloseConn 
功 能:关闭名称为Conn的默认数据库连接对像 
参 数:无 

二. 数据库操作 

下面就是本数据库操作类的函数功能说明,应该算是手册了,请多看例子的应用。 

原 型:dbCtrl.dbConn(objConn) 
功 能:获取数据库连接对像 
参 数: 
objConn : Object 已经建立的数据库连接对像 
举 例: 
Dim db : Set db = New DbCtrl 
db.dbConn = Oc(CreatConn(1,"E:\WebSite\MySite\Data\%TestDb%.mdb","","","")) 
Co(db) 

说 明:此属性为可选,如果不指定此属性则默认数据连接为页面上名称为Conn的数据库连接对像 

原 型:dbCtrl.AutoID(TableName) 
功 能:自动获取唯一序列号(自动编号) 
返回值:Integer 
参 数: 
TableName : String 需要获得唯一序列号的数据表名 
举 例: 
Dim newId 
newId = db.AutoId("TestTable") 
Response.Write(newId) 

原 型:dbCtrl.GetRecord(TableName,FieldsList,Condition,OrderField,ShowN) 
功 能:取得符合条件的纪录集 
返回值:Object 纪录集对像 
参 数: 
TableName : String 表名称 
FieldsList : String 字段名称,用逗号隔开,留空则为全部字段 
Condition : String or Array 查询条件,如果是数组应遵循前面的参数约定 
orderField : String 排序方式 
ShowN : Integer 获取纪录的数量,相当于sql中的 Select Top N 
举 例: 
Dim rs 
Set rs = db.GetRecord("TestTable","fId,fName,fAge","fSex='男' And IsActive = 1","fName Asc", 0) 
While Not rs.eof 
Response.Write ("Name is:" & rs(1) & " Age is:" & rs(2) & "<br />") 
rs.movenext() 
Wend 
db.C(rs) 

对于以上的例子,用下面的数组方式指定条件是等价的: 

Set rs = db.wGetRecord("TestTable","fId,fName,fAge", Array("fSex:男","IsActive:1"), "fName Asc", 0) 

另外,你可以用下面的语句来查看这个函数生成的sql语句: 

Response.Write(db.wGetRecord("TestTable","fId,fName,fAge", Array("fSex:男","IsActive:1"), "fName Asc", 0)) 

如你所见,只需要在原来的函数前加一个w即可。 

原 型:dbCtrl.GetRecordBySQL(strSelect) 
功 能:根据sql语句取得纪录集 
返回值:Object 纪录集对像 
参 数: 
strSelect : String 用于生成记录集的SQL语句 
举 例: 
Dim rs 
Set rs = db.GetRecordBySQL("Select a.Id, a.LastName, b.Group From User a InnerJoin Depart b On a.GroupId = b.GroupId") 
'Your Code Here ... 
db.C(rs) 

原 型:dbCtrl.GetRecordDetail(TableName, Condition) 
功 能:根据某一条指定纪录的详细数据 
返回值:Object 纪录集对像 
参 数: 
TableName : String 表名称 
Condition : String or Array 查询条件,如果是数组应遵循前面的参数约定 
举 例: 
Dim rs, Id 
Id = Request.QueryString("id") 
Set rs = db.GetRecordDetail("TestTable","Id=" & id) 
'Your Code here... 
db.C(rs) 

说 明:就像你已经看出来的一样,这个最常用在打开某个详细页面(比如新闻内容页面) 

原 型:dbCtrl.AddRecord(TableName, ValueList) 
功 能:添加一个新的纪录 
返回值:新记录的Id号(成功) or 0 (失败) 
参 数: 
TableName : String 表名称 
ValueList : Array 插入表的字段和值,只能是数组且应遵循前面的参数约定 
举 例: 
Dim fName, fSex, fWorkYear, fBirth 
fName = "王二坛" 
fSex = "男" 
fWorkYear = 12 
fBirth = Cdate("1981-10-23") 
Dim result 
result = db.AddRecord("TestTable",Array("Name:"&fName, "Sex:"&fSex, "WorkYear:"&fWorkYear, "Birthday:"&fBirth, "IsActive:True")) 
If result<>0 Then 
Response.Write("添加记录成功!此记录的自动编号Id为" & result) 
End If 

看见了吧,真的不用考虑字段的类型是什麽滴。 
如果你想要代码中的字段和值看得更清楚一点,也可以这样写,但凭卿之所好: 

result = db.AddRecord("TestTable",Array("Name:" & fName,_ 
"Sex:" & fSex,_ 
"WorkYear:" & fWorkYear,_ 
"Birthday:" & fBirth,_ 
"IsActive:True")) 

另外,你可以用下面的语句来查看这个函数生成的sql语句: 

Response.Write(db.wAddRecord("TestTable",Array("Name:"&fName, "Sex:"&fSex, "WorkYear:"&fWorkYear, "Birthday:"&fBirth, "IsActive:True"))) 

说 明:返回的Id值用的是比较笨的方法,并不能保证在并发数据量大的时候的准确性,慎用。 

原 型:dbCtrl.UpdateRecord(TableName, Condition, ValueList) 
功 能:根据指定条件更新纪录 
返回值:1 (成功) or 0 (失败) 
参 数: 
TableName : String 表名称 
Condition : String or Array 更新条件,如果是数组应遵循前面的参数约定 
ValueList : String or Array 更新的字段及值,如果是数组应遵循前面的参数约定 
举 例: 
Dim fName, fWorkYear 
fName = "王三坛" 
fWorkYear = 10 
Dim result 
result = db.UpdateRecord("TestTable", "UId = 1308", Array("Name:"&fName, "WorkYear:"&fWorkYear)) 
If result<>0 Then 
Response.Write("更新数据成功!") 
End If 

另外,你可以用下面的语句来查看这个函数生成的sql语句: 

Response.Write(db.wUpdateRecord("TestTable", "UId = 1308", Array("Name:"&fName, "WorkYear:"&fWorkYear))) 

原 型:dbCtrl.DeleteRecord(TableName,IDFieldName,IDValues) 
功 能:删除符合条件的纪录 
返回值:1 (成功) or 0 (失败) 
参 数: 
TableName : String 表名称 
IDFieldName : String 表的Id字段的名称 
IDValues : String or Array 删除条件,可以是由逗号隔开的多个Id号,如果是数组应遵循前面的参数约定 
举 例: 
Dim ids, result 
ids = Request.Form("selectid") '可以假设这裡获取的值是 12, 34, 256, 314 (复选框提交的值都这样) 
result = db.DeleteRecord("TestTable", "UId", ids) 
If result<>0 Then 
Response.Write("删除数据成功!") 
End If 

当然,你也可以用字符串或者数组指定其它的条件,比如: 

result = db.DeleteRecord("TestTable", "UId", "IsActive = 0 And FirstName = 'Tom'") 

另外,你可以用下面的语句来查看这个函数生成的sql语句: 

Response.Write(db.wDeleteRecord("TestTable", "UId", ids)) 

原 型:dbCtrl.ReadTable(TableName, Condition, GetFieldNames) 
功 能:根据指定条件获取某条纪录中的其他字段的内容 
返回值:String (GetFieldNames为单个字段) or Array (GetFieldNames为多个字段) 
参 数: 
TableName : String 表名称 
Condition : String or Array 查询条件,如果是数组应遵循前面的参数约定 
GetFieldNames : String 单个字段名或者由逗号隔开的多个字段名 
举 例: 
Dim uid, result 
uid = rs("postid") '假设这裡是页面上某个记录集中的用户id值 
result = db.ReadTable("UserTable","UId=" & uid, "UserName") 
Response.Write("发佈者:" & result) 

我不得不说,在实际应用中,这个函数可能是用得最多的,你上面看到的就是一个非常常用的例子,从一个值去获取另外一个表中某字段值等于该值的另外一个字段的值(有点拗口,不过确实就是这个意思)。下面的例子将告诉你如何根据这个值获得多个相应的值。 

Dim uid, result 
uid = rs("postid") '假设这裡是页面上某个记录集中的用户id值 
result = db.ReadTable("UserTable","UId=" & uid, "UserName,UserSex,UserAge") 
Response.Write("发佈者:" & result(0) & "<br /> 性别:" & result(1) & "<br /> 年龄:" &result(2)) 

如你所见,就这麽简单,输入多个字段名称得到的是一个数组。 

原 型:dbCtrl.C(objRs) 
功 能:关闭纪录集对像 
参 数: 
objRs : Object 页面上的某个记录集对像 
举 例: 
Dim rs 
Set rs = db.GetRecordDetail("TestTable","Id=123" ) 
'Your Code here... 
db.C(rs) 

这个函数上面的许多例子都用了,就不多解释了,它等同于rs.close : set rs = nothing。

<%
'==========================================================================
'文件名称:clsDbCtrl.asp
'功  能:数据库操作类

Dim a : a = CreatConn(0, "master", "localhost", "sa", "")	'MSSQL数据库
'Dim a : a = CreatConn(1, "Data/%TestDB%.mdb", "", "", "")	'Access数据库
'Dim a : a = CreatConn(1, "E:\MyWeb\Data\%TestDB%.mdb", "", "", "mdbpassword")
Dim Conn
'OpenConn()	'在加载时就建立的默认连接对象Conn,默认使用数据库a
Sub OpenConn : Set Conn = Oc(a) : End Sub
Sub CloseConn : Co(Conn) : End Sub

Function Oc(ByVal Connstr)
	On Error Resume Next
	Dim objConn
	Set objConn = Server.CreateObject("ADODB.Connection")
	objConn.Open Connstr
	If Err.number <> 0 Then
		Response.Write("<div id=""DBError"">数据库服务器端连接错误,请与网站管理员联系。</div>")
		'Response.Write("错误信息:" & Err.Description)
		objConn.Close
		Set objConn = Nothing
		Response.End
	End If
	Set Oc = objConn
End Function

Sub Co(obj)
	On Error Resume Next
	Set obj = Nothing
End Sub

Function CreatConn(ByVal dbType, ByVal strDB, ByVal strServer, ByVal strUid, ByVal strPwd)
	Dim TempStr
	Select Case dbType
		Case "0","MSSQL"
			TempStr = "driver={sql server};server="&strServer&";uid="&strUid&";pwd="&strPwd&";database="&strDB
		Case "1","ACCESS"
			Dim tDb : If Instr(strDB,":")>0 Then : tDb = strDB : Else : tDb = Server.MapPath(strDB) : End If
			TempStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&tDb&";Jet OLEDB:Database Password="&strPwd&";"
		Case "3","MYSQL"
			TempStr = "Driver={mySQL};Server="&strServer&";Port=3306;Option=131072;Stmt=; Database="&strDB&";Uid="&strUid&";Pwd="&strPwd&";"
		Case "4","ORACLE"
			TempStr = "Driver={Microsoft ODBC for Oracle};Server="&strServer&";Uid="&strUid&";Pwd="&strPwd&";"
	End Select
	CreatConn = TempStr
End Function


Class dbCtrl
	Private debug
	Private idbConn
	Private idbErr
	
	Private Sub Class_Initialize()
		debug = true					'调试模式是否开启
		idbErr = "出现错误:"
		If IsObject(Conn) Then
			Set idbConn = Conn
		End If
	End Sub
	
	Private Sub Class_Terminate()
		Set idbConn = Nothing
		If debug And idbErr<>"出现错误:" Then Response.Write(idbErr)
	End Sub
	
	Public Property Let dbConn(pdbConn)
		If IsObject(pdbConn) Then
			Set idbConn = pdbConn
		Else
			Set idbConn = Conn
		End If
	End Property
	
	Public Property Get dbErr()
		dbErr = idbErr
	End Property
	
	Public Property Get Version
		Version = "ASP Database Ctrl V1.0 By ColdStone"
	End Property

	Public Function AutoID(ByVal TableName)
		On Error Resume Next
		Dim m_No,Sql, m_FirTempNo
		Set m_No=Server.CreateObject("adodb.recordset")
		Sql="SELECT * FROM ["&TableName&"]"
		m_No.Open Sql,idbConn,3,3
		If m_No.EOF Then
			AutoID=1
		Else
			Do While Not m_No.EOF
				m_FirTempNo=m_No.Fields(0).Value 
				m_No.MoveNext
				  If m_No.EOF Then 
						AutoID=m_FirTempNo+1
				  End If
			Loop
		End If
		If Err.number <> 0 Then
			idbErr = idbErr & "无效的查询条件!<br />"
			If debug Then idbErr = idbErr & "错误信息:"& Err.Description
			Response.End()
			Exit Function
		End If
		m_No.close
		Set m_No = Nothing
	End Function

	Public Function GetRecord(ByVal TableName,ByVal FieldsList,ByVal Condition,ByVal OrderField,ByVal ShowN)
		On Error Resume Next
		Dim rstRecordList
		Set rstRecordList=Server.CreateObject("adodb.recordset")
			With rstRecordList
			.ActiveConnection = idbConn
			.CursorType = 3
			.LockType = 3
			.Source = wGetRecord(TableName,FieldsList,Condition,OrderField,ShowN)
			.Open 
			If Err.number <> 0 Then
				idbErr = idbErr & "无效的查询条件!<br />"
				If debug Then idbErr = idbErr & "错误信息:"& Err.Description
				.Close
				Set rstRecordList = Nothing
				Response.End()
				Exit Function
			End If	
		End With
		Set GetRecord=rstRecordList
	End Function
	
	Public Function wGetRecord(ByVal TableName,ByVal FieldsList,ByVal Condition,ByVal OrderField,ByVal ShowN)
		Dim strSelect
		strSelect="select "
		If ShowN > 0 Then
			strSelect = strSelect & " top " & ShowN & " "
		End If
		If FieldsList<>"" Then
			strSelect = strSelect & FieldsList
		Else
			strSelect = strSelect & " * "
		End If
		strSelect = strSelect & " from [" & TableName & "]"
		If Condition <> "" Then
			strSelect = strSelect & " where " & ValueToSql(TableName,Condition,1)
		End If
		If OrderField <> "" Then
			strSelect = strSelect & " order by " & OrderField
		End If
		wGetRecord = strSelect
	End Function

	Public Function GetRecordBySQL(ByVal strSelect)
		On Error Resume Next
		Dim rstRecordList
		Set rstRecordList=Server.CreateObject("adodb.recordset")
			With rstRecordList
			.ActiveConnection =idbConn
			.CursorType = 3
			.LockType = 3
			.Source = strSelect
			.Open 
			If Err.number <> 0 Then
				idbErr = idbErr & "无效的查询条件!<br />"
				If debug Then idbErr = idbErr & "错误信息:"& Err.Description
				.Close
				Set rstRecordList = Nothing
				Response.End()
				Exit Function
			End If	
		End With
		Set GetRecordBySQL = rstRecordList
	End Function

	Public Function GetRecordDetail(ByVal TableName,ByVal Condition)
		On Error Resume Next
		Dim rstRecordDetail, strSelect
		Set rstRecordDetail=Server.CreateObject("adodb.recordset")
		With rstRecordDetail
			.ActiveConnection =idbConn
			strSelect = "select * from [" & TableName & "] where " & ValueToSql(TableName,Condition,1)
			.CursorType = 3
			.LockType = 3
			.Source = strSelect
			.Open 
			If Err.number <> 0 Then
				idbErr = idbErr & "无效的查询条件!<br />"
				If debug Then idbErr = idbErr & "错误信息:"& Err.Description
				.Close
				Set rstRecordDetail = Nothing
				Response.End()
				Exit Function
			End If
		End With
		Set GetRecordDetail=rstRecordDetail
	End Function

	Public Function AddRecord(ByVal TableName, ByVal ValueList)
		On Error Resume Next
		DoExecute(wAddRecord(TableName,ValueList))
		If Err.number <> 0 Then
			idbErr = idbErr & "写入数据库出错!<br />"
			If debug Then idbErr = idbErr & "错误信息:"& Err.Description
			'DoExecute "ROLLBACK TRAN Tran_Insert"	'如果存在添加事务(事务滚回)
			AddRecord = 0
			Exit Function
		End If
		AddRecord = AutoID(TableName)-1
	End Function
	
	Public Function wAddRecord(ByVal TableName, ByVal ValueList)
		Dim TempSQL, TempFiled, TempValue
		TempFiled = ValueToSql(TableName,ValueList,2)
		TempValue = ValueToSql(TableName,ValueList,3)
		TempSQL = "Insert Into [" & TableName & "] (" & TempFiled & ") Values (" & TempValue & ")"
		wAddRecord = TempSQL
	End Function

	Public Function UpdateRecord(ByVal TableName,ByVal Condition,ByVal ValueList)
		On Error Resume Next
		DoExecute(wUpdateRecord(TableName,Condition,ValueList))
		If Err.number <> 0 Then
			idbErr = idbErr & "更新数据库出错!<br />"
			If debug Then idbErr = idbErr & "错误信息:"& Err.Description
			'DoExecute "ROLLBACK TRAN Tran_Update"	'如果存在添加事务(事务滚回)
			UpdateRecord = 0
			Exit Function
		End If
		UpdateRecord = 1
	End Function

	Public Function wUpdateRecord(ByVal TableName,ByVal Condition,ByVal ValueList)
		Dim TmpSQL
		TmpSQL = "Update ["&TableName&"] Set "
		TmpSQL = TmpSQL & ValueToSql(TableName,ValueList,0)
		TmpSQL = TmpSQL & " Where " & ValueToSql(TableName,Condition,1)
		wUpdateRecord = TmpSQL
	End Function

	Public Function DeleteRecord(ByVal TableName,ByVal IDFieldName,ByVal IDValues)
		On Error Resume Next
		Dim Sql
		Sql = "Delete From ["&TableName&"] Where ["&IDFieldName&"] In ("
		If IsArray(IDValues) Then
			Sql = Sql & "Select ["&IDFieldName&"] From ["&TableName&"] Where " & ValueToSql(TableName,IDValues,1)
		Else
			Sql = Sql & IDValues
		End If
		Sql = Sql & ")"
		DoExecute(Sql)
		If Err.number <> 0 Then
			idbErr = idbErr & "删除数据出错!<br />"
			If debug Then idbErr = idbErr & "错误信息:"& Err.Description
			'DoExecute "ROLLBACK TRAN Tran_Delete"	'如果存在添加事务(事务滚回)
			DeleteRecord = 0 
			Exit Function
		End If
		DeleteRecord = 1
	End Function
	
	Public Function wDeleteRecord(ByVal TableName,ByVal IDFieldName,ByVal IDValues)
		On Error Resume Next
		Dim Sql
		Sql = "Delete From ["&TableName&"] Where ["&IDFieldName&"] In ("
		If IsArray(IDValues) Then
			Sql = Sql & "Select ["&IDFieldName&"] From ["&TableName&"] Where " & ValueToSql(TableName,IDValues,1)
		Else
			Sql = Sql & IDValues
		End If
		Sql = Sql & ")"
		wDeleteRecord = Sql
	End Function 

	Public Function ReadTable(ByVal TableName,ByVal Condition,ByVal GetFieldNames)
		On Error Resume Next
		Dim rstGetValue,Sql,BaseCondition,arrTemp,arrStr,TempStr,i
		TempStr = "" : arrStr = ""
		'给出SQL条件语句
		BaseCondition = ValueToSql(TableName,Condition,1)
		'读取数据
		Set rstGetValue = Server.CreateObject("ADODB.Recordset")
		Sql = "Select "&GetFieldNames&" From ["&TableName&"] Where "&BaseCondition
		rstGetValue.Open Sql,idbConn,3,3
		If rstGetValue.RecordCount > 0 Then
			If Instr(GetFieldNames,",")>0 Then
				arrTemp = Split(GetFieldNames,",")
				For i = 0 To Ubound(arrTemp)
					If i<>0 Then arrStr = arrStr &Chr(112)&Chr(112)&Chr(113)
					arrStr = arrStr & rstGetValue.Fields(i).Value
				Next
				TempStr = Split(arrStr,Chr(112)&Chr(112)&Chr(113))
			Else
				TempStr = rstGetValue.Fields(0).Value
			End If
		End If
		If Err.number <> 0 Then
			idbErr = idbErr & "获取数据出错!<br />"
			If debug Then idbErr = idbErr & "错误信息:"& Err.Description
			rstGetValue.close()
			Set rstGetValue = Nothing
			Exit Function
		End If
		rstGetValue.close()
		Set rstGetValue = Nothing
		ReadTable = TempStr
	End Function

	Public Function C(ByVal ObjRs)
		ObjRs.close()
		Set ObjRs = Nothing
	End Function
	
	Private Function ValueToSql(ByVal TableName, ByVal ValueList, ByVal sType)
		Dim StrTemp
		StrTemp = ValueList
		If IsArray(ValueList) Then
			StrTemp = ""
			Dim rsTemp, CurrentField, CurrentValue, i
			Set rsTemp = Server.CreateObject("adodb.recordset")
			With rsTemp
				.ActiveConnection = idbConn
				.CursorType = 3
				.LockType = 3
				.Source ="select * from [" & TableName & "] where 1 = -1"
				.Open
				For i = 0 to Ubound(ValueList)
					CurrentField = Left(ValueList(i),Instr(ValueList(i),":")-1)
					CurrentValue = Mid(ValueList(i),Instr(ValueList(i),":")+1)
					If i <> 0 Then
						Select Case sType
							Case 1
								StrTemp = StrTemp & " And "
							Case Else
								StrTemp = StrTemp & ", "
						End Select
					End If
					If sType = 2 Then
						StrTemp = StrTemp & "[" & CurrentField & "]"
					Else
						Select Case .Fields(CurrentField).Type
							Case 7,133,134,135,8,129,200,201,202,203
								If sType = 3 Then
									StrTemp = StrTemp & "'"&CurrentValue&"'"
								Else
									StrTemp = StrTemp & "[" & CurrentField & "] = '"&CurrentValue&"'"
								End If
							Case 11
								If UCase(cstr(Trim(CurrentValue)))="TRUE" Then
									If sType = 3 Then
										StrTemp = StrTemp & "1"
									Else
										StrTemp = StrTemp & "[" & CurrentField & "] = 1"
									End If
								Else 
									If sType = 3 Then
										StrTemp = StrTemp & "0"
									Else
										StrTemp = StrTemp & "[" & CurrentField & "] = 0"
									End If
								End If
							Case Else
								If sType = 3 Then
									StrTemp = StrTemp & CurrentValue
								Else
									StrTemp = StrTemp & "[" & CurrentField & "] = " & CurrentValue
								End If
						End Select
					End If
				Next
			End With
			If Err.number <> 0 Then
				idbErr = idbErr & "生成SQL语句出错!<br />"
				If debug Then idbErr = idbErr & "错误信息:"& Err.Description
				rsTemp.close()
				Set rsTemp = Nothing
				Exit Function
			End If
			rsTemp.Close()
			Set rsTemp = Nothing
		End If
		ValueToSql = StrTemp
	End Function

	Private Function DoExecute(ByVal sql)
		Dim ExecuteCmd
		Set ExecuteCmd = Server.CreateObject("ADODB.Command")
		With ExecuteCmd
			.ActiveConnection = idbConn
			.CommandText = sql
			.Execute
		End With
		Set ExecuteCmd = Nothing
	End Function
End Class
%>
<%Session.CodePage=936%>
<!--#include file="clsDbctrl.asp" -->
<%
Dim db : Set db = New DbCtrl   'create object
db.dbConn = Oc(a)   'create connect
Dim rs : Set rs = db.GetRecordBySQL("select * from product order by ID Asc")  'create rs -GetRecordBySQL
While Not rs.eof   
Response.Write ("Name is:" & rs("id") & " Age is:" & rs("Title") & "<br />")   
rs.movenext()   
Wend   
db.C(rs)   'close rs
Co(db) : CloseConn() 'close object,close    connect
%>


本文转载自:http://blog.csdn.net/smartsmile2012/article/details/8189283

共有 人打赏支持
深圳大道
粉丝 3
博文 877
码字总数 0
作品 0
深圳
架构师
私信 提问
PHP比ASP优秀的七个理由

摘要:PHP比ASP优秀的七个理由 SP是微软公司实现动态网页的一种技术。ASP支持一些脚本语言,主要以VBScripp为主。与ASP相比较,你还可以选择另一中开放源代码编程语言——PHP,PHP可以运行在...

xiaodaiyy11
2011/12/08
747
7
在项目中迁移MS SQLServer到Mysql数据库,实现MySQL数据库的快速整合

在开发项目的时候,往往碰到的不同的需求情况,兼容不同类型的数据库是我们项目以不变应万变的举措之一,在底层能够兼容多种数据库会使得我们开发不同类型的项目得心应手,如果配合快速的框架...

伍华聪
2018/09/07
0
0
ASP.NET性能优化之分布式Session

如果我们正在使用Session,那么构建高性能可扩展的ASP.NET网站,就必须解决分布式Session的架构,因为单服务器的SESSION处理能力会很快出现性能瓶颈,这类问题也被称之为Session同步。微软有...

晨曦之光
2012/06/08
119
0
sql server,mysql,oracle三者的区别

oracle就是ORACLE公司的数据库产品,以高性能著称,系统是可以随意下载的,但应用与商业用途需要LECENCE;MS SQL是微软的数据库产品特点是易学易用,交互性好,具有良好的用户界面,,定位是中型企业...

aminqiao
2014/06/12
0
1
linux环境php调用sqlServer2000存储过程遇到的问题

  在linux环境中用php查询sql server并不是很常见的需求.一般来说如果一定要用sql server,编程语言我会先c#;如果一定要用php,数据库我就选mysql.   这几天的开发中,需要从一个非开源的e...

吕明明
2013/03/14
0
0

没有更多内容

加载失败,请刷新页面

加载更多

Java单例模式学习记录

在项目开发中经常能遇见的设计模式就是单例模式了,而实现的方式最常见的有两种:饿汉和饱汉(懒汉)。由于日常接触较多而研究的不够深入,导致面试的时候被询问到后有点没底,这里记录一下学习...

JerryLin123
昨天
3
0
VSCODE 无法调试

VSCODE 无法调试 可以运行 可能的原因: GCC 的参数忘了加 -g

shzwork
昨天
4
0
理解去中心化 稳定币 DAI

随着摩根大通推出JPM Coin 稳定币,可以预见稳定币将成为区块链落地的一大助推器。 坦白来讲,对于一个程序员的我来讲(不懂一点专业经济和金融),理解DAI的机制,真的有一点复杂。耐心看完...

Tiny熊
昨天
4
0
5.线程实现

用于线程实现的Python模块 Python线程有时称为轻量级进程,因为线程比进程占用的内存少得多。 线程允许一次执行多个任务。 在Python中,以下两个模块在一个程序中实现线程 - _thread 模块 th...

Eappo_Geng
昨天
6
0
ServiceLoader

创建一个接口文件在resources资源目录下创建META-INF/services文件夹在services文件夹中创建文件,以接口全名命名创建接口实现类 内容me.zzp.ar.d.PostgreSQLDialectme.zzp.ar.d.Hype...

Cobbage
昨天
6
0

没有更多内容

加载失败,请刷新页面

加载更多

返回顶部
顶部