文档章节

elixir官方教程 元编程(二) 宏

ljzn
 ljzn
发布于 2016/08/14 00:22
字数 2223
阅读 1576
收藏 11

#宏

  1. 前言
  2. 我们的第一个宏
  3. 宏的隔离
  4. 环境
  5. 私有宏
  6. 负责任地编写宏

#前言

尽管Elixir已竭力为宏提供一个安全的环境,用宏编写干净代码的责任仍然落在了开发者身上.宏比传统的Elixir函数更难编写,而且在不必要的场合使用宏是不好的.所以请负责任地编写宏.

Elixir已经提供了许多数据结构和函数,能够让你以简单可读的风格编写日常代码.宏应当是最后的选择.记住,明显胜过含蓄.清晰的代码胜过简洁的代码.

#我们的第一个宏

ELixir中使用defmacro/2来定义宏.

本章,我们将使用文件来代替在IEx中运行样本代码.这是因为代码样本将跨越许多行,将它们全部输入IEx会适得其反.你应当将代码样本保存进macro.exs文件,并使用elixir macros.exsiex macro.exs来运行.

为了更好地理解宏是如何运作的,让我们创建一个新的模块,在其中实现unless,它的作用与if相反.分别以函数和宏的形式:

defmodule Unless do
  def fun_unless(clause, expression) do
    if(!clause, do: expression)
  end

  defmacro macro_unless(clause, expression) do
    quote do
      if(!unquote(clause), do: unquote(expression))
    end
  end
end

函数接收了参数,并传送给if.然而正如我们在前一章所学过的,宏会接收引用表达式,将它们注入引用,最后返回另一个引用表达式.

让我们用iex运行上面的模块:

$ iex macros.exs

调戏一下那些定义:

iex> require Unless
iex> Unless.macro_unless true, IO.puts "this should never be printed"
nil
iex> Unless.fun_unless true, IO.puts "this should never be printed"
"this should never be printed"
nil

注意,在宏的实现中,句子没有被打印,然而在函数的实现中,句子被打印了.这是因为函数的参数会在调用函数之前被执行.而宏不会执行它们的参数.它们以引用表达式的形式接收参数,之后又将其变形为其它引用表达式.本例中,我们实际上是将unless宏重写成了一个if.

换句话说,当被这样调用时:

Unless.macro_unless true, IO.puts "this should never be printed"

我们的macro_unless宏接收到了:

macro_unless(true, {{:., [], [{:aliases, [], [:IO]}, :puts]}, [], ["this should never be printed"]})

然后返回了一个引用表达式:

{:if, [],
 [{:!, [], [true]},
  [do: {{:., [],
     [{:__aliases__,
       [], [:IO]},
      :puts]}, [], ["this should never be printed"]}]]}

我们可以使用Macro.expand_once/2来验证它:

iex> expr = quote do: Unless.macro_unless(true, IO.puts "this should never be printed")
iex> res  = Macro.expand_once(expr, __ENV__)
iex> IO.puts Macro.to_string(res)
if(!true) do
  IO.puts("this should never be printed")
end
:ok

Macro.expand_once/2接收了引用表达式,并根据当前环境扩展了它.本例中,它扩展/调用了Unless.macro_unless/2宏,并返回了结果.之后我们将返回的引用表达式转换成一个字符串并打印出来(我们将在本章稍后的位置讨论__ENV__).

这就是宏.它们接收引用表达式并将其变形为别的东西.事实上,Elixir中的unless/2是作为宏来实现的:

defmacro unless(clause, options) do
  quote do
    if(!unquote(clause), do: unquote(options))
  end
end

本教程中用到的许多纯Elixir实现的结构都是宏,例如unless/2,defmacro/2,def/2,defprotocol/2等等.这意味着,开发者可以用构建语言的结构来将语言扩展到它们工作的领域.

我们可以定义任何函数和宏,甚至覆盖Elixir中的原本定义.唯一的例外是Elixir特殊形式,它们不是由Elixir实现的,因此不能被覆盖,特殊形式的完整列表可以在Kernel.SpecialForms中找到.

#宏的隔离(Macros hygiene)

Elixir的宏有着低决定权.这保证了引用中的变量定义不会与宏被扩展到的语境中的变量定义相冲突.例如:

defmodule Hygiene do
  defmacro no_interference do
    quote do: a = 1
  end
end

defmodule HygieneTest do
  def go do
    require Hygiene
    a = 13
    Hygiene.no_interference
    a
  end
end

HygieneTest.go
# => 13

上述例子中,即使宏注入了a = 1,却没有影响到变量a在函数go中的定义.如果宏想要明确地影响语境,可以使用var!:

defmodule Hygiene do
  defmacro interference do
    quote do: var!(a) = 1
  end
end

defmodule HygieneTest do
  def go do
    require Hygiene
    a = 13
    Hygiene.interference
    a
  end
end

HygieneTest.go
# => 1

因为Elixir使用变量的语境来注解它,所以能够实现变量隔离.例如,一个模块的第三行定义的变量x可以被表示成:

{:x, [line: 3], nil}

然而一个引用变量是这样表示的:

defmodule Sample do
  def quoted do
    quote do: x
  end
end

Sample.quoted #=> {:x, [line: 3], Sample}

注意引用变量的第三个元素是原子Sample,而不是nil,它标记了变量是来自Sample模块的.因此,Elixir认为这两个变量来自不同语境,会分别处理它们.

Elixir也为进口(imports)和别名(aliases)提供了相似的机制.这保证了宏的行为会与它源模块中的定义相同,而不是与宏所扩展到的目标模块相冲突.使用类似var!/2alias!/2之类的宏可以突破隔离,但是它们必须小心使用,因为这直接改变了用户环境.

有时,变量名会被动态地创建.Macro.var/2可用于定义新变量:

defmodule Sample do
  defmacro initialize_to_char_count(variables) do
    Enum.map variables, fn(name) ->
      var = Macro.var(name, nil)
      length = name |> Atom.to_string |> String.length
      quote do
        unquote(var) = unquote(length)
      end
    end
  end

  def run do
    initialize_to_char_count [:red, :green, :yellow]
    [red, green, yellow]
  end
end

> Sample.run #=> [3, 5, 6]

注意Macro.var/2的第二个变量.在下一节中我们将知道它是所使用的语境,而且能定义隔离.

#环境

本章早些时候,我们调用Macro.expand_once/2时,使用了特殊形式__ENV__.

__ENV__返回了一个Macro.Env结构的实例,它包含了编译环境的有用信息,包括当前模块,文件和行,所有定义在当前作用域中的变量,还有imports,requires等等.

iex> __ENV__.module
nil
iex> __ENV__.file
"iex"
iex> __ENV__.requires
[IEx.Helpers, Kernel, Kernel.Typespec]
iex> require Integer
nil
iex> __ENV__.requires
[IEx.Helpers, Integer, Kernel, Kernel.Typespec]

Macro模块中的许多函数都期望一个环境.你可以在Macro模块中找到关于这些函数,以及在Macro.Env的文档中找到关于编译环境的更多信息.

#私有宏

Elixir也支持私有宏,使用defmacrop来定义.和私有函数一样,这些宏只能在它的定义模块中使用,而且只在编译时.

很重要的一点是,宏在使用之前定义.没有在调用一个宏之前定义它,将会在运行时抛出一个错误,因为宏不会被扩展,而且将会被转化成函数调用:

iex> defmodule Sample do
...>  def four, do: two + two
...>  defmacrop two, do: 2
...> end
** (CompileError) iex:2: function two/0 undefined

#负责任地编写宏

宏是很强大的结构,Elixir提供了许多机制来确保它们被负责任地使用.

- 宏是隔离的: 定义在宏内的变量默认是不会影响用户代码的.而且,宏语境中的函数调用和别名是不会泄露到用户语境中的.

- 宏具有词典性质: 不可能全局地注入代码或宏.为了使用宏,你需要明确地requireimport定义了宏的模块.

- 宏是明确的: 宏不可能在没有明确被导入的情况下运行.例如,一些语言允许开发者在内部完全重写函数,通常是通过语义转换或一些反射机制.在Elixir中,编译时,宏必须在调用者中被明确导入.

- 宏的语言是清晰的: 许多语言为quoteunquote提供了语法捷径.在Elixir中,我们更愿意它们被明确地拼写出来,以便清楚地划出宏定义与它的引用表达式间的界限.

即使有这些保障,开发者仍在负责任地编写宏这件事中扮演重要角色.如果你确信你需要使用宏,记住宏不是你的API.你的宏定义要保持简短,包括它们的引用内容.例如,与其像这样编写宏:

defmodule MyModule do
  defmacro my_macro(a, b, c) do
    quote do
      do_this(unquote(a))
      ...
      do_that(unquote(b))
      ...
      and_that(unquote(c))
    end
  end
end

不如这样:

defmodule MyModule do
  defmacro my_macro(a, b, c) do
    quote do
      # Keep what you need to do here to a minimum
      # and move everything else to a function
      do_this_that_and_that(unquote(a), unquote(b), unquote(c))
    end
  end

  def do_this_that_and_that(a, b, c) do
    do_this(a)
    ...
    do_that(b)
    ...
    and_that(c)
  end
end

这使得你的代码更清晰,也更容易测试和维护,因为你可以直接调用和测试do_this_that_and_that/3.这也有助于你为那些不愿意依赖宏的开发者来设计一个实际的API.

现在,我们结束了对宏的介绍.下一章我们将简短得讨论DSL,展示如何混合宏和模块属性,来注释和扩展模块与函数.

© 著作权归作者所有

共有 人打赏支持
ljzn
粉丝 29
博文 69
码字总数 96245
作品 0
南平
程序员
私信 提问
加载中

评论(3)

自主创新
自主创新
我喜欢草泥马语法,简介明了 只有2个字符
0Scn
0Scn
其实我更喜欢erlang的语法,233;有map了,也不用纠结太多了。
leeyi
leeyi
感觉elixir的语法和erlang差别太大了,有点让我排查它的语法
elixir官方入门教程 学习资料

下一步该去哪 构建你的第一个Elixir项目 元编程 社区与其它资源 Erlang基础 想要学习更多?继续阅读! 构建你的第一个Elixir项目 为了开始你的第一个项目,Elixir装载了一个叫做Mix的构建工具....

ljzn
2016/08/06
144
0
elixir官方教程 元编程(一) 引用与去引用

引用与去引用 引用(Quoting) 去引用(Unquoting) 释放(Escaping) 一个Elixir程序可以用它自己的数据结构来表现.本章,我们将会学习这些结构体的特点和如何组成它们.本章我们要学习的概念是为宏...

ljzn
2016/08/13
44
0
Elixir 学习资源

Elixir 官网 getting started官方入门学习资源 官方文档 hex 包管理系统 elixir sips 比较不错视频课程 Elixir China 中文论坛 官方wiki Elixir by Example Awesome Elixir Elixir Quiz 通过...

lidashuang
2017/11/29
0
0
elixir官方入门教程 别名,要求与进口

别名,要求与进口 别名 要求 进口 使用 理解别名 模块嵌套 群体别名/进口/要求/使用 为了方便软件复用,Elixir提供了三个命令(,和)外加一个宏,简介如下: 现在我们将详细探索它们.记住前三条之所...

ljzn
2016/08/04
255
2
从 Go 开发者的角度看 Elixir 的设计思想

从 Go 开发者的角度看 Elixir 的设计思想 免责声明: 这篇文章不是带你入门的,我只是把玩了一下这个编程语言,也不是什么专家,就把我写的当做一道开胃菜吧。我只是把我几个小时的调研结果汇...

drkaka
2016/01/07
5.7K
4

没有更多内容

加载失败,请刷新页面

加载更多

iOS 官方文档

https://developer.apple.com/library/prerelease/content/navigation/#section=Platforms&topic=iOS...

walking_yxf
5分钟前
0
0
使用Mycat实现MySQL数据库的读写分离

前提准备 1.一台CentOS机器 2.Mycat安装包 (http://www.mycat.io/) 安装使用 1.解压Mycat的安装包到/user/local/下 2.设置mycat的环境变量 vi /etc/profile 3.使配置文件立即生效 source /...

吴伟祥
5分钟前
0
0
Aries数据库事务Recovery算法

背景知识 本文是一篇关于(分布式)数据库的文章,在开始阐述Aries是什么之前,需要先交代几个常识性的概念,这些概念对后文引出Aries显得尤为重要。 数据库体系结构 图1大致描述了一个(分布...

黑客画家
8分钟前
0
0
Rxjava Backpressure 32

原文:https://github.com/Froussios/Intro-To-RxJava/blob/master/Part 4 - Concurrency/4. Backpressure.md Rx将事件从管道的一端引导到另一端,在每一端发生的行动可能非常不同。当生产者...

woshixin
9分钟前
0
0
IDEA-Create Git Repository

1、概述 idea 开发完毕的项目没有及时的关联gitlab,如果整体项目关联gitlab。 2、干 2.1 gitlab 创建项目 2.2 idea 1、IDEA 点击 -> VCS -> import into version control -> create git re......

来来来来来
12分钟前
0
0

没有更多内容

加载失败,请刷新页面

加载更多

返回顶部
顶部