文档章节

ini 文件操作记要(1): 使用 TIniFile

涂孟超
 涂孟超
发布于 2014/09/26 15:38
字数 782
阅读 4
收藏 1
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure Button7Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses IniFiles;  {uses 包含 TIniFile 的单元}

var
  ini: TIniFile;
  path: string;         {ini 文件路径}
  Section,Key: string;  {分别表示 ini 文件的小节与关键字}

{
  ini文件结构:
  ;注释
  [小节名]
  关键字=值

  INI文件支持: string、integer、boolean、Date、Time、DateTime、Double 与二进制类型
  string 值没有引号
  boolean 的真假用 1、0 表示
}

procedure TForm1.FormCreate(Sender: TObject);
begin
  path := ChangeFileExt(ParamStr(0),'.ini');
  ini := TIniFile.Create(path);  {ini 对象建立需要文件路径参数, 如果缺少路径会默认Windows目录}
end;

//写入 ini 文件:
procedure TForm1.Button1Click(Sender: TObject);
begin
  Section := 'AAA';
  Key := 'AString';
  ini.WriteString(Section,Key,'AAA-String');

  Key := 'AInteger';
  ini.WriteInteger(Section,Key,111);

  Key := 'ABoolean';
  ini.WriteBool(Section,Key,True);

  Key := 'ADate';
  ini.WriteDate(Section,Key,Now);

  Key := 'ATime';
  ini.WriteTime(Section,Key,Now);

  Key := 'ADateTime';
  ini.WriteDateTime(Section,Key,Now);

  Key := 'ADouble';
  ini.WriteFloat(Section,Key,Pi);


  Section := 'BBB';
  Key := 'BString';
  ini.WriteString(Section,Key,'BBB-String');

  Key := 'BInteger';
  ini.WriteInteger(Section,Key,222);

  Key := 'BBoolean';
  ini.WriteBool(Section,Key,True);

  Key := 'BDate';
  ini.WriteDate(Section,Key,Now);

  Key := 'BTime';
  ini.WriteTime(Section,Key,Now);

  Key := 'BDateTime';
  ini.WriteDateTime(Section,Key,Now);

  Key := 'BDouble';
  ini.WriteFloat(Section,Key,Pi);


  Section := 'CCC';
  Key := 'CString';
  ini.WriteString(Section,Key,'CCC-String');

  Key := 'CInteger';
  ini.WriteInteger(Section,Key,333);

  Key := 'CBoolean';
  ini.WriteBool(Section,Key,False);

  Key := 'CDate';
  ini.WriteDate(Section,Key,Now);

  Key := 'CTime';
  ini.WriteTime(Section,Key,Now);

  Key := 'CDateTime';
  ini.WriteDateTime(Section,Key,Now);

  Key := 'CDouble';
  ini.WriteFloat(Section,Key,Pi);

{写入结果:
  [AAA]
  AString=AAA-String
  AInteger=111
  ABoolean=1
  ADate=2007-12-17
  ATime=22:06:23
  ADateTime=2007-12-17 22:06:23
  ADouble=3.14159265358979
  [BBB]
  BString=BBB-String
  BInteger=222
  BBoolean=1
  BDate=2007-12-17
  BTime=22:06:23
  BDateTime=2007-12-17 22:06:23
  BDouble=3.14159265358979
  [CCC]
  CString=CCC-String
  CInteger=333
  CBoolean=0
  CDate=2007-12-17
  CTime=22:06:23
  CDateTime=2007-12-17 22:06:23
  CDouble=3.14159265358979
}
end;

//读取 ini 文件:
procedure TForm1.Button2Click(Sender: TObject);
var
  s: string;
  i: Integer;
  b: Boolean;
  f: Double;
  d: TDate;
  t: TTime;
  dt: TDateTime;
begin
  s := ini.ReadString('BBB','BString','');  {最后一个参数是默认值}
  i := ini.ReadInteger('BBB','BInteger',0);
  b := ini.ReadBool('BBB','BBoolean',False);
  f := ini.ReadFloat('BBB','BDouble',0);
  d := ini.ReadDate('BBB','BDate',Now);
  t := ini.ReadTime('BBB','BTime',Now);
  dt := ini.ReadDateTime('BBB','BDateTime',Now);

  ShowMessage(s);                 {BBB-String}
  ShowMessage(IntToStr(i));       {222}
  ShowMessage(BoolToStr(b));      {-1(True)}
  ShowMessage(FloatToStr(f));     {3.14159265358979}
  ShowMessage(DateToStr(d));      {2007-12-17}
  ShowMessage(TimeToStr(t));      {22:06:23}
  ShowMessage(DateTimeToStr(dt)); {2007-12-17 22:06:23}
end;

//读入所有小节名到 TStrings:
procedure TForm1.Button3Click(Sender: TObject);
var
  List: TStrings;
begin
  List := TStringList.Create;
  List.LoadFromFile(Path);
  ini.ReadSections(List);
  ShowMessage(List.Text);
  {
    AAA
    BBB
    CCC
  }
  List.Free;
end;

//读入指定小节的所有关键字到 TStrings:
procedure TForm1.Button4Click(Sender: TObject);
var
  List: TStrings;
begin
  List := TStringList.Create;
  ini.ReadSection('AAA',List);
  ShowMessage(List.Text);
  {
    AString
    AInteger
    ABoolean
    ADate
    ATime
    ADateTime
    ADouble
  }
  List.Free;
end;

//读入指定小节的所有关键字与值到 TStrings:
procedure TForm1.Button5Click(Sender: TObject);
var
  List: TStrings;
begin
  List := TStringList.Create;
  ini.ReadSectionValues('BBB',List);
  ShowMessage(List.Text);
  {
    BString=BBB-String
    BInteger=222
    BBoolean=1
    BDate=2007-12-17
    BTime=22:06:23
    BDateTime=2007-12-17 22:06:23
    BDouble=3.14159265358979
  }
  List.Free;
end;

//删除与添加
procedure TForm1.Button6Click(Sender: TObject);
begin
  ini.DeleteKey('BBB','BString');  {删除关键字}
  ini.EraseSection('CCC');         {删除小节}
//  ini.UpdateFile;                {保存到文件}

{添加小节与关键字或修改值, 直接写入即可}
end;

//其他功能
procedure TForm1.Button7Click(Sender: TObject);
var
  b: Boolean;
  s: string;
begin
  b := ini.SectionExists('DDD');         {判断某个小节是否存在}
  b := ini.ValueExists('AAA','AString'); {判断某个关键字的值是否存在}
  s := ini.FileName;                     {获取文件名}
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ini.Free;
end;

end.

 
 
 
 
 

 

 

  

本文转载自:http://www.cnblogs.com/del/archive/2007/12/17/1003755.html

共有 人打赏支持
涂孟超
粉丝 12
博文 2011
码字总数 14107
作品 0
深圳
程序员
delphi ini 文件读取

1.INI文件的结构:;这是关于INI文件的注释部分[节点]关键字=值 2.使用两层循环读取ini文件节点和节点中的属性 使用以下文件测试:[某某1]name=某某1gender=0ege=26birthday=0.0hobby=篮球、桌...

hyhlinux
2016/07/27
35
0
Delphi截获webbrowser中关闭及右键消息处理一例

procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean); var setINI: Tinifile; oldPoint, newPoint: TPOINT; begin if Msg.message = WM_CLOSE then {//判断......

任远
2016/06/15
12
0
Visual C++中巧妙遍历INI配置文件

Visual C++中巧妙遍历INI配置文件 /函数功能:INI文件的遍历函数参数: 1 pFilePath ini文件的路径 *///inline void EnumIniFile(LPCTSTR pFilePath, CString strKey,map<CString,int>& map_Ke......

IMGTN
2012/12/01
0
0
delphi pchar char byte string转换问题

delphi pchar char byte string转换问题 注:Delphi中的Char,PChar,PByte,Byte,String的相互转换,您是不是也遇到过,为此头疼过吗?你要是明白了他们的原理就会轻松了。 话题064840的标题是...

鹅倌
2017/01/06
0
0
关于文件操作集锦 delphi

关于文件操作集锦 取得该快捷方式的指向EXE 关键词:快捷方式 LNK unit Unit1; interface uses Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCt......

vga
2014/04/23
0
0

没有更多内容

加载失败,请刷新页面

加载更多

WinDbg

参考来自:http://www.cnit.net.cn/?id=225 SRV*C:\Symbols*http://msdl.microsoft.com/download/symbols ctrl + d to open dump_file Microsoft (R) Windows Debugger Version 6.12.0002.633......

xueyuse0012
今天
2
0
OSChina 周五乱弹 —— 想不想把92年的萝莉退货

Osc乱弹歌单(2018)请戳(这里) 【今日歌曲】 @罗马的王:分享松澤由美的单曲《地球ぎ》 很久没看圣斗士星矢了 《地球ぎ》- 松澤由美 手机党少年们想听歌,请使劲儿戳(这里) @开源中国首...

小小编辑
今天
12
1
springBoot条件配置

本篇介绍下,如何通过springboot的条件配置,控制Bean的创建 介绍下开发环境 JDK版本1.8 springboot版本是1.5.2 开发工具为 intellij idea(2018.2) 开发环境为 15款MacBook Pro 前言 很多时候,...

贺小五
今天
1
0
javascript source map 的使用

之前发现VS.NET会为压缩的js文添加一个与文件名同名的.map文件,一直没有搞懂他是用来做什么的,直接删除掉运行时浏览器又会报错,后来google了一直才真正搞懂了这个小小的map文件背后的巨大...

粒子数反转
昨天
1
0
谈谈如何学Linux和它在如今社会的影响

昨天,还在农耕脑力社会,今天已经人工智能技术、大数据、信息技术的科技社会了,高速开展并迅速浸透到当今科技社会的各个方面,Linux日益成为人们信息时代的到来,更加考验我们对信息的处理程...

linux-tao
昨天
1
0

没有更多内容

加载失败,请刷新页面

加载更多

返回顶部
顶部