文档章节

学习 TTreeView [3] - Add、AddChild、AddFirst、AddChildFirst、Parent

涂孟超
 涂孟超
发布于 2014/09/26 15:35
字数 704
阅读 13
收藏 0
本例效果图:


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    TreeView1: TTreeView;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{方法1: 按职务顺序入场}
procedure TForm1.Button1Click(Sender: TObject);
var
  Nodes: TTreeNodes;
  node: TTreeNode;
begin
  Nodes := TreeView1.Items;

  {添加第一个元素}
  node := Nodes.Add(nil, '一连长'); {'一连长'好孤独, 旁边没人}

  {现在 node 代表"一连长", 继续添加与其平级人员, 当然要参照"一连长"}
  Nodes.Add(node, '二连长');
  Nodes.Add(node, '三连长');

  {安排"一连"的下一层: "排长"; 同时让 node 指向"一排长"}
  node := Nodes.AddChild(node, '一排长');
  Nodes.Add(node, '二排长');
  Nodes.Add(node, '三排长');

  {添加平级用 Add, 添加下级用 AddChild; 继续:}
  node := Nodes.AddChild(node, '一班长');
  Nodes.Add(node, '二班长');
  Nodes.Add(node, '三班长');

  {还有 AddChildFirst 和 AddFirst 是专门添加第一个的, 假如忘了第一个...}
  node := Nodes.AddChild(node, '战士2');
  Nodes.Add(node, '战士3');
  Nodes.Add(node, '战士4');
  Nodes.AddFirst(node, '战士1'); {用 AddFirst 可以让它站在前面}
end;


{方法2: 按先后顺序入场}
procedure TForm1.Button2Click(Sender: TObject);
var
  Nodes: TTreeNodes;
  node: TTreeNode;
begin
  Nodes := TreeView1.Items;

  node := Nodes.Add(nil, '一连长');
  node := Nodes.AddChild(node, '一排长');
  node := Nodes.AddChild(node, '一班长');
  node := Nodes.AddChild(node, '战士1');
  Nodes.Add(node, '战士2');
  Nodes.Add(node, '战士3');
  Nodes.Add(node, '战士4');

  node := node.Parent;       {让 node 指向上一层}
  Nodes.Add(node, '二班长');
  Nodes.Add(node, '三班长');

  node := node.Parent;
  Nodes.Add(node, '二排长');
  Nodes.Add(node, '三排长');

  node := node.Parent;
  Nodes.Add(node, '二连长');
  Nodes.Add(node, '三连长');
end;


{方法3: 因为没使用 TTreeNodes 和 TTreeNode, 挺麻烦的}
procedure TForm1.Button3Click(Sender: TObject);
begin
  TreeView1.Items.Add(nil, '一连长');
  TreeView1.Items.Add(TreeView1.Items[0], '二连长');
  TreeView1.Items.Add(TreeView1.Items[0], '三连长');

  TreeView1.Items.AddChild(TreeView1.Items[0], '一排长');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0], '二排长');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0], '三排长');

  TreeView1.Items.AddChild(TreeView1.Items[0].Item[0], '一班长');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0].Item[0], '二班长');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0].Item[0], '三班长');

  TreeView1.Items.AddChild(TreeView1.Items[0].Item[0].Item[0], '战士1');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0].Item[0].Item[0], '战士2');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0].Item[0].Item[0], '战士3');
  TreeView1.Items.Add(TreeView1.Items[0].Item[0].Item[0].Item[0], '战士4');
end;


{方法4: 用 with 简化了"方法3", 也够绕的; 推荐使用前两种方法}
procedure TForm1.Button4Click(Sender: TObject);
begin
  with TreeView1 do begin
    Items.Add(nil, '一连长');
    Items.Add(Items[0], '二连长');
    Items.Add(Items[0], '三连长');

    Items.AddChild(Items[0], '一排长');
    Items.Add(Items[0].Item[0], '二排长');
    Items.Add(Items[0].Item[0], '三排长');

    Items.AddChild(Items[0].Item[0], '一班长');
    Items.Add(Items[0].Item[0].Item[0], '二班长');
    Items.Add(Items[0].Item[0].Item[0], '三班长');

    Items.AddChild(Items[0].Item[0].Item[0], '战士1');
    Items.Add(Items[0].Item[0].Item[0].Item[0], '战士2');
    Items.Add(Items[0].Item[0].Item[0].Item[0], '战士3');
    Items.Add(Items[0].Item[0].Item[0].Item[0], '战士4');
  end;
end;


procedure TForm1.Button5Click(Sender: TObject);
begin
  TreeView1.Items.Clear;
  TButton(Sender).Caption := '清空';
end;

end.

 
 
 
 
 

 

 

  

本文转载自:http://www.cnblogs.com/del/archive/2008/03/11/1100604.html

共有 人打赏支持
涂孟超
粉丝 12
博文 2011
码字总数 14107
作品 0
深圳
程序员
RecyclerView实现倒序列表

RecyclerView实现倒序列表 标签(空格分隔): android RecyclerView 倒序 1、写在前面 实现一个聊天界面,就是类似QQ那种,这里是讲一下倒序排列,不实现QQ的各种高级功能 2、ListView 反转...

走正路
2016/06/16
1K
0
govcl v1.0.4 释出,GO 语言 UI 组件库

1、增加了TListView、TTreeView、TPageControl几个事件; 2、增加了TListView、TTreeView排序过程; 3、修复了New控件时使用CheckPtr增加安全检测; 4、增加了TListView、TTreeView排序,图像...

不在乎y
2017/12/21
2.4K
14
Java中LinkedList笔记

之前写程序似乎也没有怎么关注过底层的结构,最近正好遇到了链表的问题,于是仔细阅读了Java中链表的实现LinkedList 简单记录一下看完的总结: 1.LinkedList中定义了一个类型Node<E> ,包括3...

小翼Eric
2015/07/28
0
0
lufylegend-HTML5游戏引擎学习笔记4:绘图进阶

上篇: http://my.oschina.net/wolfx/blog/632130 使用原始canvas绘图 API: http://lufylegend.com/api/zh_CN/out/classes/LGlobal.html 用形状裁剪图片 API: http://lufylegend.com/api/zh_......

WolfX
2016/03/07
122
0
JAVA 私塾第八、九章笔记整理

JAVA 私塾第八、九章笔记整理 第八章 异常和断言 一. 异常的分类 java.lang.Throwable类充当所有对象的父类,可以使用异常处理机制将这些对象超出并捕获。有Error和Exception两个基本子类。...

luodis
2011/02/15
130
1

没有更多内容

加载失败,请刷新页面

加载更多

下一页

阿里云API网关使用教程

API 网关(API Gateway)提供高性能、高可用的 API 托管服务,帮助用户对外开放其部署在 ECS、容器服务等阿里云产品上的应用,提供完整的 API 发布、管理、维护生命周期管理。用户只需进行简...

mcy0425
35分钟前
4
0
解决远程登陆误按ctrl+s锁屏假死恢复

使用putty时,偶尔发生屏幕假死,不能输入等情况。 后来发现,只要数据ctrl+s,就会假死;输入ctrl+q就可以恢复过来。 很多刚从windows转移到linux上来工作的朋友,在用vi/vim编辑文件时,常常...

HJCui
38分钟前
0
0
@Transactional

事务管理是应用系统开发中必不可少的一部分。Spring 为事务管理提供了丰富的功能支持。Spring 事务管理分为编程式和声明式的两种方式。编程式事务指的是通过编码方式实现事务;声明式事务基于...

asdf08442a
42分钟前
2
0
widows下强制解除8080端口占用问题

使用win+R打开命令窗口 输入以下命令查看哪个任务占用了8080端口 netstat -ano |findstr "8080" 然后通过任务id强制关闭占用该端口的进程 tskill 10044 // 自己的试情况而定,这个ID是LISTE...

_Artisan
52分钟前
2
0
productFlavors简单实用

最近项目中,不同环境需要配置的参数越来越多,为了减少修改代码次数。研究了一下productFlavors的使用方式,总结如下 1. as3.0以上版本使用productFlavors时需要指定一个flavorDimensions,...

火云
54分钟前
1
0

没有更多内容

加载失败,请刷新页面

加载更多

下一页

返回顶部
顶部