文档章节

使用 InputBox、InputQuery 的启发

涂孟超
 涂孟超
发布于 2014/09/26 15:33
字数 1109
阅读 10
收藏 0

看了 InputBox、InputQuery 函数实现的源码, 有些收获与心得...

通过 InputBox 可获取用户输入的字符串:
procedure TForm1.Button1Click(Sender: TObject);
var
  str: string;
begin
  str := InputBox('输入窗口标题', '输入提示', '默认输入内容');
  ShowMessage(str); //显示输入的内容
end;

 
 
 
 
 

 

 

  

InputBox 是调用了 InputQuery, InputQuery 是通过一个 var 参数获取新字串:
procedure TForm1.Button2Click(Sender: TObject);
var
  str: string;
begin
  InputQuery('输入窗口标题', '输入提示', str);
  ShowMessage(str); //显示输入的内容
end;

 
 
 
 
 

 

 

  

InputQuery 可返回一个 Boolean 值, 可判断用户是确认还是取消, 挺有用的:
procedure TForm1.Button3Click(Sender: TObject);
var
  str: string;
begin
  str := '默认输入内容';
  if InputQuery('输入窗口标题', '输入提示', str) then
    ShowMessage(str); //如果点击了 ok 按钮将显示输入的内容
end;

 
 
 
 
 

 

 

  

我经常用到需要用户输入或选择的窗口, 一般都是 Show 一个提前设计好的窗口; 这会浪费资源, InputQuery 的窗口应该是动态建立的.

但如果动态建立还是有诸多麻烦, 譬如给按钮添加事件...

但查看 InputQuery 的源码, 只有区区几十行, 果然是动态建立的窗口, 但并没有发现 "事件" 相关的代码!

再看下去, 发现这和 "模式窗口" 有关, 假如不是用 ShowModal 启动窗口的话, 恐怕 "事件" 代码是非写不可.

那 "模式窗口" 中的 "按钮" 和 "模式窗口" 又是如何关联的呢?

还是做起来看吧:

//主体代码就这些:
procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm;
begin
  frm := TForm.Create(Application);
  frm.ShowModal;
  frm.Free;
end;

 
 
 
 
 

 

 

  

同时动态添加进两个按钮:
procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm;
begin
  frm := TForm.Create(Application);

  with TButton.Create(frm) do begin
    Caption := '确认';
    Parent := frm;
    Left := 100; top := 40;
  end;

  with TButton.Create(frm) do begin
    Caption := '取消';
    Parent := frm;
    Left := 100; top := 80;
  end;

  frm.ShowModal;
  frm.Free;
end;

 
 
 
 
 

 

 

  

但上面代码写出的按钮并没有任何作用, 其实只要设置一下按钮的 ModalResult 属性就可以了:
procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm;
begin
  frm := TForm.Create(Application);

  with TButton.Create(frm) do begin
    Caption := '确认';
    ModalResult := mrOk; {1}
    Parent := frm;
    Left := 100; top := 40;
  end;

  with TButton.Create(frm) do begin
    Caption := '取消';
    ModalResult := mrCancel; {2}
    Parent := frm;
    Left := 100; top := 80;
  end;

  frm.ShowModal;
  frm.Free;
end;

 
 
 
 
 

 

 

  

按钮的 ModalResult 属性就是一个整数, 窗体也有相同的属性; 点击按钮时它会传递给所属窗体的同名(ModalResult)属性; 这个属性的默认值是 0, 非 0 时模式窗口即刻关闭.

另外: ShowModal 是个函数, 调用时会返回窗口的 ModalResult 值.

上面几句话挺重要, 我也都从相关源码中核实了.
procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm;
begin
  frm := TForm.Create(Application);

  with TButton.Create(frm) do begin
    Caption := '确认';
    ModalResult := mrOk; {1}
    Parent := frm;
    Left := 100; top := 40;
  end;

  with TButton.Create(frm) do begin
    Caption := '取消';
    ModalResult := mrCancel; {2}
    Parent := frm;
    Left := 100; top := 80;
  end;

  if frm.ShowModal = mrOk then
    ShowMessage('确认了')
  else
    ShowMessage('没有确认');

  frm.Free;
end;

 
 
 
 
 

 

 

  

完善一下, 并添加两个文本框准备接受信息:
procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm;
begin
  frm := TForm.Create(Application);
  frm.Position := poScreenCenter;
  frm.ClientWidth := 270;
  frm.ClientHeight := 100;
  frm.Caption := '输入对话框';

  with TEdit.Create(frm) do begin
    Parent := frm;
    Name := 'Edit1';
    SetBounds(10, 10, 100, 20);
  end;

  with TEdit.Create(frm) do begin
    Parent := frm;
    Name := 'Edit2';
    SetBounds(150, 10, 100, 20);
  end;

  with TButton.Create(frm) do begin
    Caption := '确认';
    ModalResult := mrOk;
    Default := True;
    Parent := frm;
    SetBounds(100, 40, 75, 25);
  end;

  with TButton.Create(frm) do begin
    Caption := '取消';
    ModalResult := mrCancel;
    Cancel := True;
    Parent := frm;
    SetBounds(100, 70, 75, 25);
  end;

  if frm.ShowModal = mrOk then
  begin
    ShowMessage('确认了');
  end;

  frm.Free;
end;

 
 
 
 
 

 

 

  

如何传回用户输入的信息呢? 我觉得用类似 InputQuery 函数中的 var 参数接受信息就挺好的, 这种方式用于接受复杂的信息也很方便; 不过要先把上面的代码写到一个函数里:
{函数}
function GetInfo(var str1,str2: string): Boolean;
var
  frm: TForm;
  MyEdit1, MyEdit2: TEdit;
begin
  Result := False;
  frm := TForm.Create(Application);
  frm.Position := poScreenCenter;
  frm.ClientWidth := 270;
  frm.ClientHeight := 100;
  frm.Caption := '输入对话框';

  MyEdit1 := TEdit.Create(frm);
  with MyEdit1 do begin
    Parent := frm;
    Text := str1;
    SetBounds(10, 10, 100, 20);
  end;

  MyEdit2 := TEdit.Create(frm);
  with MyEdit2 do begin
    Parent := frm;
    Text := str2;
    SetBounds(150, 10, 100, 20);
  end;

  with TButton.Create(frm) do begin
    Caption := '确认';
    ModalResult := mrOk;
    Default := True;
    Parent := frm;
    SetBounds(100, 40, 75, 25);
  end;

  with TButton.Create(frm) do begin
    Caption := '取消';
    ModalResult := mrCancel;
    Cancel := True;
    Parent := frm;
    SetBounds(100, 70, 75, 25);
  end;

  if frm.ShowModal = mrOk then
  begin
    str1 := MyEdit1.Text;
    str2 := MyEdit2.Text;
    Result := True;
  end;

  frm.Free;
end;

{调用测试}
procedure TForm1.Button1Click(Sender: TObject);
var
  s1,s2: string;
begin
  s1 := 'aaa';
  s2 := 'bbb';
  if GetInfo(s1, s2) then ShowMessageFmt('%s - %s', [s1, s2]);
end;

 
 
 
 
 

 

 

  

完成了, 但这远远没有 InputQuery 的源码精彩; 不过从今往后再用到一个采集信息的对话框时, 我会尽量用这样一个函数来完成; 这就是我阅读 InputQuery 源码的收获.

本文转载自:http://www.cnblogs.com/del/archive/2009/10/08/1579174.html

共有 人打赏支持
涂孟超
粉丝 12
博文 2011
码字总数 14107
作品 0
深圳
程序员
私信 提问
unity安卓移动端读写Xml实例

翻别人的博客,翻来翻去试来试去,翻到了一些东西,撞来撞去后终于撞到对的结果 之前总感觉好难啊,不想看啊,跳了。后来还是躲不过。移动端的路径什么的还是要弄懂啊, 路径一直是个问题。之...

ou_nvhai的博客
2017/12/19
0
0
VBS脚本:计算还需要净胜多少局才能让自己的扫雷胜率增长1%

程序说明 作为一个扫雷爱好者,今天突然想做一个脚本,看看自己还剩下多少局才能让胜率增长1个百分点 脚本通过已玩游戏数和已胜游戏数,推算还需要连胜多少局游戏才能让自己的获胜率增长一个...

北风其凉
2014/12/29
0
0
如何用VBS编写一个简单的恶搞脚本

windows系统的电脑, 首先右击桌面,选择新建-文本文档,在桌面上新建一个文本文档; image.png 随后打开计算机或者是我的电脑,点击其中的组织(xp系统多为工具),选择下面的文件夹和搜索选...

_周小董
2017/12/04
0
0
VB 实现二分查找

VB 实现二分查找 tiankonguse blog2014-10-29205 阅读 vb查找 背景 女朋友要把代码贴给我,我说把cpp文件发给我吧。 结果老婆发给我一个 vbp 文件,原来是VB编写的。我想难道 VB 代码以 vbp ...

tiankonguse blog
2014/10/29
0
0
window.prompt 的设置[摘]

自定义prompt window.prompt = (function(prompt) { if (window.navigator.appName.toLowerCase().indexOf("microsoft")<0) return prompt; return function(msg) { window.vbs_var = null; ......

于子洋
2010/03/08
411
0

没有更多内容

加载失败,请刷新页面

加载更多

如何在React工程中使用JavaScript Barcode SDK创建Web条形码应用

基于WebAssembly构建的Dynamsoft JavaScript Barcode SDK让Web开发者能够创建适用于浏览器的高性能条码应用。这篇文章分享下如何使用React快速创建一个简单的Web条形码扫描应用。 下载 Node...

yushulx
30分钟前
1
0
java lambda笔记

c#中的lambda表达式简直不要太爽,但是感觉java的lambda和c#比有待继续提高。 先搞个筛选List集合的东西,我们先搞个集合玩玩。 List<Person> person = new ArrayList<Person>();Person p...

朝如青丝暮成雪
30分钟前
0
0
最严新规发布 网络短视频平台该如何降低违规风险?

1月9日中国网络视听节目服务协会对外正式发布了多项规范,对版权视频保护及违规内容,都进行了更加详细的标准制定,整体政策更加严格。 规范规定,网络短视频平台应当履行版权保护责任,不得...

阿里云官方博客
38分钟前
1
0
深入解读阿里云数据库POLARDB核心功能物理复制技术

日志是数据库的重要组成部份,按顺序以增量的方式记录了数据库上所有的操作,日志模块的设计对于数据库的可靠性、稳定性和性能都非常重要。 可靠性方面,在有一个数据文件的基础全量备份后,...

zhaowei121
44分钟前
1
0
CentOS 非root 用户 使用sudo 命令免密码

1. 使用su/su - 命令进入root权限下; 2. 给/etc/sudoers文件添加写权限 chmod u+w /etc/sudoers 3.找到“root ALL=(ALL) ALL ”,在后面添加:"dba ALL=(ALL) NOPASSWD: ALL" 4.保存退出,并......

驛路梨花醉美
44分钟前
1
0

没有更多内容

加载失败,请刷新页面

加载更多

返回顶部
顶部